Ren’Pyで背景画像をループさせる

Ren’Pyで背景画像をループさせる方法です。以下の変換を適当な場所で定義してください。

transform loop_L(i, s):
    subpixel True
    contains:
        xpos 1.
        xanchor 1.
        i
        block:
            linear s xanchor 2.
            xanchor 0.
            linear s xanchor 1.
            repeat
    contains:
        xpos 1.
        i
        block:
            linear 2*s xanchor 2.
            xanchor 0.
            repeat
transform loop_R(i, s):
    subpixel True
    contains:
        xpos 1.
        xanchor 1.
        i
        block:
            linear s xanchor 0.
            xanchor 2.
            linear s xanchor 1.
            repeat
    contains:
        xpos 1.
        xanchor 2.
        i
        block:
            linear 2*s xanchor 0.
            xanchor 2.
            repeat
transform loop_U(i, s):
    subpixel True
    contains:
        ypos 1.
        yanchor 1.
        i
        block:
            linear s yanchor 2.
            yanchor 0.
            linear s yanchor 1.
            repeat
    contains:
        ypos 1.
        i
        block:
            linear 2*s yanchor 2.
            yanchor 0.
            repeat
transform loop_D(i, s):
    subpixel True
    contains:
        ypos 1.
        yanchor 1.
        i
        block:
            linear s yanchor 0.
            yanchor 2.
            linear s yanchor 1.
            repeat
    contains:
        ypos 1.
        yanchor 2.
        i
        block:
            linear 2*s yanchor 0.
            yanchor 2.
            repeat

使用可能になる変換


loop_U(i, s), loop_D(i, s), loop_L(i, s), loop_R(i, s)
    i:
        画像名またはファイルのパスです。画像の大きさは画面幅の整数倍を想定しています。
    s:
        1周にかける秒数です。
それぞれ上下左右方向に画像をループします。


label start:
        show expression loop_R("bg loop", 3) as loop

loop
クリックするとアニメーションを開始します。

21/12/05 追記
現在はx, ypan transform プロパティーが追加され以下だけで可能になりました。

show bg loop:
    xpan 0
    linear 3 xpan 360
    repeat
Pocket

コメントを残す

メールアドレスが公開されることはありません。 が付いている欄は必須項目です